Demo-FillForm — заполнение форм на сайтах

Макрос Demo-FillForm.iim

Макрос Demo-FillForm.iim демонстрирует: как можно автоматически заполнять формы на сайтах, используя iMacros.

Описание работы Demo-FillForm.iim:

Строка 1 — указание версии (VERSION) iMacros Browser на которой был написан данный макрос.

Строка 2 — объявляется TAB о том, что работать будем в текущей вкладке (первой), если пишете для себя, то данная строка необязательна.

Строка 3 — закрываем все вкладки кроме активной.

Строка 4 — открываем сайт по ссылке URL.

Строка 5 — при помощи команды TAG iMacros находим первый элемент попадающий под фильтр: HTML-элемент <INPUT> с type = «text» и атрибутом (ATTR) id = «name», находящийся в форме <FORM> c id = «demo». При помощи параметра CONTENT, содержащего текст в кавычках (кавычки используются так как текст содержит пробел) заполняем найденный элемент.

Строка 6 — командой TAG находим первый элемент попадающий под фильтр: HTML-элемент <SELECT> и атрибутом (ATTR) id = «food», находящийся в форме <FORM> c id = «demo». При помощи параметра CONTENT, содержащего текст «%Pizza» происходит выбор элемента (клик).

Строка 7 — полностью аналогичен строке 6.

Примечание: строки 6-7 выбираются по значение пунктов, а не по их положению в списке.

Строка 8 — командой TAG находим первый элемент попадающий под фильтр: HTML-элемент <INPUT> с type = «radio» и атрибутом (ATTR) id = «medium» и содержащим значение (value) medium, находящийся в форме <FORM> c id = «demo». При помощи параметра CONTENT, содержащего текст «YES» происходит выбор данного пункта (переключается радио-кнопка).

Строка 9 — похож на строки 6-7, только при помощи параметра CONTENT происходит выбор нескольких пунктов, для этого они разделенных двоеточием (:).

Строка 10 — аналогично строке 8.

Строка 11 — при помощи команды SET устанавливаем значение переменной !ENCRIPTION в положение NO.

Строка 12 — вводится пароль, пароль записывается в значение параметра CONTENT.

Строка 13 — заполняется поле TEXTAREA. Для форматирования текста, в скобках можно использовать: \n — для перехода на новую строку, \t — отступ в начале строки, \" — для использования кавычек.

Строка 14 — клик по кнопке.

Код макроса:

VERSION BUILD=10.4.28.1074
TAB T=1
TAB CLOSEALLOTHERS
URL GOTO=http://demo.imacros.net/Automate/TestForm1
TAG POS=1 TYPE=INPUT:TEXT FORM=ID:demo ATTR=ID:name CONTENT="iMacros Help"
TAG POS=1 TYPE=SELECT FORM=ID:demo ATTR=ID:food CONTENT=%Pizza
TAG POS=1 TYPE=SELECT FORM=ID:demo ATTR=ID:drink CONTENT=%Coke
TAG POS=1 TYPE=INPUT:RADIO FORM=ID:demo ATTR=ID:medium&&VALUE:medium CONTENT=YES
TAG POS=1 TYPE=SELECT FORM=ID:demo ATTR=ID:dessert CONTENT=%ice<SP>cream:%Apple<SP>Pie
TAG POS=1 TYPE=INPUT:RADIO FORM=ID:demo ATTR=NAME:Customer CONTENT=YES
SET !ENCRYPTION NO
TAG POS=1 TYPE=INPUT:PASSWORD FORM=ID:demo ATTR=NAME:Reg_code CONTENT=пароль
TAG POS=1 TYPE=TEXTAREA FORM=ID:demo ATTR=NAME:Remarks CONTENT="Здравствуйте!\n\n \t С iMacrosHelp вы узнаете как заполнять формы;-)\n\nВладислав"
TAG POS=1 TYPE=BUTTON:SUBMIT FORM=ID:demo ATTR=TXT:Click<SP>to<SP>order<SP>now

 

Оставить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *