Demo-Web-Test — пример веб-тестирования

Макрос Demo-Web-Test.iim

Пример Demo-Web-Test демонстрирует использование команды STOPWATCH для автоматизированного веб-тестирования. Данный пример может использоваться как с плагинами для IE и Firefox, так и в iMacros Browser.

При помощи макроса проверяется полное время на выполнение макроса, время затраченное на вход в систему и выполнение поиска по товарным знакам на сайте «Бюро патентов и товарных знаков США» (http://www.uspto.gov), а также время загрузки страницы, время на получение результатов поиска и время на поиск документов для загрузки.

Макрос можно и даже нужно запускать в различное время, чтобы получить результаты в разное время дня и ночи, когда нагрузка на сайт меняется. Для сайта бюро характерна интенсивная нагрузка в течении рабочего дня в США, и значительно ниже в ночное время.

Файл .csv создается при первом прогоне, а затем данные только добавляются к уже существующему файлу с отметками времени и даты, что позволяет легко сравнивать их при помощи Excel или любой другой программе работающей с таблицами, даже Google Sheet.

Описание работы Demo-Web-Test.iim:

Строка 1 — стандартная строка, описывающая версию (VERSION) iMacros Browser на которой был написан данный макрос.

Строка 2 — объявляется TAB о том, что работать будем в открытой вкладке (первой), если пишете для себя, то эту строку можно пропустить.

Строка 3 — закрываем все вкладки кроме активной (что бы они не повлияли на работоу сценария).

Строка 4 — при помощи команды SET задаем переменной !FILESTOPWATCH файл usptoTiming.csv, в который будем записывать результаты работы команд STOPWATCH.

Строка 5-6 — задаем начальное время отсчета команды STOPWATCH, с идентификаторами (ID) fullsearch и websiteload.

Строка 7 — открываем сайт по ссылке URL.

Строка 8 — останавливаем время отсчета для таймера (STOPWATCH) с ID websiteload. Записываем полученное значение в файл, указанный в строке 4.

Далее при помощи команды TAG производятся простые клики по элементам, так же снимаются показания таймеров как в строке 8.

Строка 20 — выполняется команда BACK, которая возвращает на предыдущую страницу (как кнопка назад в браузере).

Строка 21 — при помощи команды TAG находим первый элемент попадающий под фильтр: HTML-элемент <INPUT> c type = «SUBMIT» который расположен внутри формы (<FORM>), (у которой атрибут ACTION = /bin/gate.exe). У искомого элемента есть атрибут (ATTR) NAME = a_logout. И нажимаем на данный элемент.

Строка 22 — останавливаем время отсчета для таймера (STOPWATCH) с ID fullsearch. Записываем рассчитанное значение в файл.

Код макроса:

VERSION BUILD=10.4.28.1074
TAB T=1         
TAB CLOSEALLOTHERS  
SET !FILESTOPWATCH usptoTimings.csv   
STOPWATCH ID=fullsearch 
STOPWATCH ID=websiteload
URL GOTO=http://www.uspto.gov/#     
STOPWATCH ID=websiteload
TAG POS=1 TYPE=A ATTR=TXT:Trademarks   
TAG POS=1 TYPE=A ATTR=TXT:Quick<SP>Links
TAG POS=1 TYPE=A ATTR=TXT:TESS
TAG POS=1 TYPE=A ATTR=TXT:Word<SP>and/or<SP>Design<SP>Mark<SP>Search<SP>(Free<SP>Form)  
STOPWATCH ID=search
TAG POS=1 TYPE=TEXTAREA FORM=NAME:search_text ATTR=NAME:p_s_ALL CONTENT=78829872[SN]<SP>
TAG POS=1 TYPE=INPUT:SUBMIT FORM=NAME:search_text ATTR=NAME:a_search
STOPWATCH ID=search 
STOPWATCH ID=opendocument
TAG POS=1 TYPE=IMG ATTR=SRC:http://tmsearch.uspto.gov/webaka/icon/reg/tsdr.gif
STOPWATCH ID=opendocument    
BACK    
TAG POS=1 TYPE=INPUT:SUBMIT FORM=ACTION:/bin/gate.exe ATTR=NAME:a_logout  
STOPWATCH ID=fullsearch

Оставить комментарий

Ваш e-mail не будет опубликован. Обязательные поля помечены *